#!/usr/bin/awk
# Emacs-Time-stamp: "2006-01-05 12:30:49"
# Emacs-File-stamp: "/home/cymbala/leninist.biz/lb-db__.awk"
# ASSUMPTION: Records are in chronological order, and, most recent record
# has most up-to-date information.
## ------------------------------------------------------------------
## $ ~/.../1972/291cmtttc$ awk -f ~/leninist.biz/lb-db__.awk .index
## __TITLE__        A Critique of Mao Tse-Tung's Theoretical Conceptions
## __AUTHOR__       Krivtsov, V.A. & Sidikhmenov, V.Y. (Editors-in-Chief)
## __AUTHOR_LONG__  Editorial Board:
##                  F.~V. KONSTANTINOV, M.~I. SLADKOVSKY
##                  V.~G. GEORGIYEV,
##                  (Editors-in-Chief),
##                  V.~A. KRIVTSOV, V.~Y. SIDIKHMENOV
## __SOURCE__            ysverdlov library.
## $ ~/leninist.biz/en/progmosc/1972/291cmtttc$ 
## $ ~/leninist.biz/en/progmosc/1972/291cmtttc$ 
## ------------------------------------------------------------------
BEGIN {
    # Group who-type fields at top in order given by file "__".
    while (getline gl < "/home/cymbala/leninist.biz/__") {
	# WAS: 2005.06.16: /<<WHO/
	if (gl ~ /<<WHO[0-9][0-9][^a-z]/) {
	    split(gl, array);
	    who[nwho++] = array[2];
	}
    }
    who[nwho++] = "__TITLE__";
}
NR == 1 {
    tags_exclude["__TYPE__"] = 0;
    tags_exclude["__MEANING__"] = 0;
}
# Delete counter.
previous == "" && $0 ~ /^[0-9]+$/ {
    gsub(/[0-9]+/, "");
}
# Delete record header.
previous == "" && $0 ~ /^[12][0-9][0-9][0-9][.][0-9][0-9][.][0-9][0-9][ 	][0-2][0-9][:][0-5][0-9][:][0-5][0-9]/ {
    gsub(/.*/, "");
}
# Delete whitespace from blank lines.
/^[ 	]*$/ {
    gsub(/[ 	]+/, "");
}
$1 ~ /^__[^ 	]+__$/ {
    tag = $1; 
    # Reset.
    if ( ! ( tag in tags_exclude ) ) {
	if ( ! ( tag in tagsn ) ) {
	    tags[++ntags] = tag;
	    tagsn[tag] = ntags;
	}
    }
    db[tags[tagsn[tag]]] = "";
}
{
    if (tag && $0) {
	if ( ! ( tag in tags_exclude ) ) {
	    db[tags[tagsn[tag]]] = db[tags[tagsn[tag]]] $0 "\n";
	}
    }
    previous = $0;
}
END {
    # who[n] = __TAG__
    for (i=0; i<=nwho; i++) {
	tag = who[i];
	whotags[tag] = 0;
	data = db[tag];
	if ( data ) {
	    if ( data !~ /=-=-=/ ) {
		printf "%s", data;
	    }
	}
    }
    for (i=1; i<=ntags; i++) {
	tag = tags[i];
	data = db[tag];
	if ( ! ( tag in whotags ) ) {
	    if ( data !~ /=-=-=/ ) {
		printf "%s", data;
	    }
	}
    }
}
###
#